P-Spice Simulation
P-Spice Listing 1-4 zur Simulation des bipolaren Transistors
**********************************************
**MULTIMEDIAPROJEKT Listing 1**
** Schaltverhalten des **
** bipolaren Transistors BU508A **
** Emittlung der Ein- und Ausschaltzeiten **
** bei ohmscher Last **
*********************************************
****** ANSTEUERUNG DES TRANSISTORS *****
I1 0 3 PULSE(0 {STROM} 10u 0.3u 0.3u 10u 60u)
********************************************
********* VERSORGUNGSSPANNUNG *********
V1 2 0 DC 25
********************************************
************* LASTWIDERSTAND ************
RL 2 1 57
********************************************
** HAUPTPARAMETER DES TRANSISTOR-MODEL **
QBU 1 3 0 BU508A
.MODEL BU508A NPN BF=32.8 RC=0.06 RB=0.6 IS=20.5FA IKF=0.67 ISE=393PA
+ NE=1.7 NF=0.9 BR=1.5 CJC=415PF CJE=415PF VAF=100
+ TF=22n XTF=2 ITF=0.6 VTF=3 TR=10U VAR=100
********************************************
.PARAM STROM=84m
.TRAN 100n 100U 0 100n
.PROBE
.END
********************************************
********************************************
**MULTIMEDIAPROJEKT Listing 2**
** Schaltverhalten des **
** bipolaren Transistors BU508A **
** Emittlung der Ein- und Ausschaltzeiten **
** bei ohmscher Last **
********************************************
******* ANSTEUERUNG DES TRANSISTORS ********
I1 0 3 PULSE(0 {STROM} 10u 0.3u 0.3u 10u 60u)
********************************************
*** NEGATIVE ANSTEUERUNG DES TRANSISTORS ***
I2 0 3 PULSE(0 {NEGSTROM} 20u 0.3u 0.3u 7.5u 60u)
********************************************
*********** VERSORGUNGSSPANNUNG ************
V1 2 0 DC 25
********************************************
************** LASTWIDERSTAND **************
RL 2 1 57
********************************************
*** HAUPTPARAMETER DES TRANSISTOR-MODEL ****
QBU 1 3 0 BU508A
.MODEL BU508A NPN BF=32.8 RC=0.06 RB=0.6 IS=20.5FA IKF=0.67 ISE=393PA
+ NE=1.7 NF=0.9 BR=1.5 CJC=415PF CJE=415PF VAF=100
+ TF=22n XTF=2 ITF=0.6 VTF=3 TR=10U VAR=100
********************************************
.PARAM NEGSTROM=-28m
.PARAM STROM=84m
.TRAN 100n 100U 0 100n
.PROBE
.END
********************************************
**********************************************
** MULTIMEDIAPROJEKT Listing 3 **
** Schaltverhalten des **
** bipolaren Transistor BU508A **
** Ermittlung der Ein- und Ausschaltzeiten **
** unter Einfluss der Antisaettigungsdioden **
**********************************************
********* ANSTEUERUNG DES TRANSISTOR *********
I1 0 4 PULSE(0 {STROM} 10u 0.3u 0.3u 10u 60u)
**********************************************
************ VERSORGUNGSSPANNUNG *************
V1 20 0 25
RS 20 2 10
**********************************************
*************** LASTWIDERSTAND ***************
RL 2 1 47
**********************************************
**** HAUPTPARAMETER DES TRANSISTOR-MODEL *****
QBU 1 3 0 BU508A
.MODEL BU508A NPN BF=32.8 RC=0.06 RB=0.6 IS=20.5FA IKF=0.67 ISE=393PA
+ NE=1.7 NF=0.9 BR=1.5 CJC=415PF CJE=415PF VAF=100
+ TF=22n XTF=2 ITF=0.6 VTF=3 TR=10u VAR=100
**********************************************
*********** Antisaettigungsdioden ************
D1 4 1 DTEST
D2 3 4 DTEST
D3 4 3 DTEST
.Model DTEST D (TT=450n)
**********************************************
.PARAM STROM=84m
.TRAN 100n 100U 0 100n
.PROBE
.END
**********************************************
*****************************************
**MULTIMEDIAPROJEKT Listing 4**
** Schaltverhalten des **
** bipolaren Transistor BU508A **
** bei ohmsch- induktiver Last **
*****************************************
****** ANSTEUERUNG DES TRANSISTOR *******
I1 0 3 PULSE(0 {STROM} 10u 0.3u 0.3u 10u 60u)
*****************************************
********** VERSORGUNGSSPANNUNG **********
V1 20 0 DC 25
RS 20 2 10
*****************************************
********* OHMSCH-INDUKTIVE LAST *********
L1 2 1 800u
RK 2 4 1G
CK 2 4 1n
L2 4 5 800u
k1 L1 L2 0.99999
D1 6 4 DTEST
.MODEL DTEST D (TT=450n)
RL 5 6 {LAST}
*****************************************
** HAUPTPARAMETER DES TRANSISTOR-MODEL **
QBU 1 3 0 BU508A
.MODEL BU508A NPN BF=32.8 RC=0.06 RB=0.6 IS=20.5FA IKF=0.67 ISE=393PA
+ NE=1.7 NF=0.9 BR=1.5 CJC=415PF CJE=415PF VAF=100
+ TF=22n XTF=2 ITF=0.6 VTF=3 TR=10U VAR=100
******************************************
.PARAM LAST=67
.PARAM STROM=84m
.TRAN 100n 100U 0 100n
.PROBE
.END
******************************************
P-Spice Listing 5 zur Simulation des IGBT
*********************************************
**MULTIMEDIAPROJEKT Listing 5 **
** Schaltverhalten des **
** N-Kanal IGBT BUK854 **
** Ermittlung der Ein- und Ausschaltzeiten **
** bei ohmscher Last **
*********************************************
*********** ANSTEUERUNG DES IGBT ************
VGE 1 0 pulse ( 0 15 0 0.3u 0.3u 10u 60u)
RG 1 2 50
*********************************************
************ VERSORGUNGSSPANNUNG ************
VCE 4 0 dc 25
*********************************************
************** LASTWIDERSTAND ***************
RL 4 3 57
*********************************************
**************** IGBT BUK854 ****************
X1 3 2 0 buk854
.inc g:buk854.mod
*********************************************
.TRAN 100n 120u 0 100n
.PROBE
.END
*********************************************
P-Spice Listing 6 zur Simulation des MOSFET
*********************************************
**MULTIMEDIAPROJEKT Listing 6 **
** Schaltverhalten des **
** N-Kanal- MOSFET IRF 150 **
** Ermittlung der Ein- und Ausschaltzeiten **
*********************************************
********** ANSTEUERUNG DES MOSFET ***********
V1 10 0 PULSE(0 15 10u 0.3u 0.3u 10u 60u)
RG 10 1 {RGATE}
*********************************************
************ VERSORGUNGSSPANNUNG ************
VDS 20 0 dc 25
*********************************************
************** LASTWIDERSTAND ***************
RL 20 2 57
*********************************************
****** HAUPTPARAMETER DES MOSFET-MODEL *****
M1 2 1 0 0 IRF150
.model IRF150 NMOS(Level=3 Gamma=0 Delta=0 Eta=0 Theta=0 Kappa=0
+ Vmax=0 Xj=0 Tox=100n Uo=600 Phi=.6 Rs=1.624m Kp=20.53u
+ W=0.3 L=2u Vto=2.831 Rd=1.031m Rds=444.4K Cbd=3.229n
+ Pb=0.8 Mj=0.5 Fc=0.5 Cgso=9.027n Cgdo=1.679n Rg=13.89
+ IS=194E-18 N=1 Tt=288n)
*********************************************
.PARAM RGATE=50
.TRAN 100n 120u 0 100n
.probe
.end
*********************************************
zurück